docs: Tester-Feedback zu Sync und Hub festhalten
- Sync wurde von den Fachtestern nicht genutzt: Sie planen am PC und drucken aus. Sync bleibt als Funktion für andere Käufer, wird aber nicht ausgebaut; der Ausdruck ist der Weg, den die PDF-Ausgabe tragen muss. - Der Kür-Hub ist ebenfalls ungenutzt, hat aber anderes Potential: Die Tester wohnen weit auseinander, und der Hub ist der einzige Weg, sich gegenseitig Küren zu zeigen. Abwarten, bevor investiert wird. - `tests/manual/render_print_sample.gd` erzeugt ein Beispiel-PDF zum Prüfen des Ausdrucks (nicht Teil der Testsuite).
This commit is contained in:
parent
ed1228190f
commit
f7c5fe2e1f
2 changed files with 105 additions and 0 deletions
|
|
@ -119,6 +119,16 @@ Webseite). Das Google-Drive-Backend ist im Code vorhanden, aber die
|
|||
OAuth-App ist nicht veröffentlicht. Google Drive und OneDrive stehen unter
|
||||
„Später: Weitere Cloud-Anbieter“.
|
||||
|
||||
**Rückmeldung der Fachtester (2026-11-13):** Sync wurde nicht genutzt – die
|
||||
Tester arbeiten zuhause am PC und drucken die Abläufe aus. Sync bleibt als
|
||||
Funktion (für andere Käufer und mehrere Geräte), wird aber nicht ausgebaut.
|
||||
Der Ausdruck ist damit der Weg, den die PDF-Ausgabe tragen muss.
|
||||
|
||||
**Kür-Hub:** ebenfalls noch ungenutzt, aber mit anderem Potential: Die
|
||||
Tester wohnen weit auseinander, und der Hub ist der einzige Weg, sich
|
||||
gegenseitig Küren zu zeigen. Abzuwarten, ob dieser Effekt greift, bevor hier
|
||||
investiert wird.
|
||||
|
||||
### Erledigt: Element-Marker
|
||||
|
||||
- [x] Sprungpunkte, Pirouettenzentren und Sequenzbereiche platzieren
|
||||
|
|
|
|||
95
rinkplanner/tests/manual/render_print_sample.gd
Normal file
95
rinkplanner/tests/manual/render_print_sample.gd
Normal file
|
|
@ -0,0 +1,95 @@
|
|||
extends SceneTree
|
||||
|
||||
## Erzeugt eine Beispieldatei zum Prüfen des Ausdrucks. Nicht Teil der Tests.
|
||||
|
||||
const PathSegmentModel := preload("res://src/core/model/path_segment.gd")
|
||||
|
||||
|
||||
func _init() -> void:
|
||||
_run.call_deferred()
|
||||
|
||||
|
||||
func _run() -> void:
|
||||
var routine := Routine.new()
|
||||
routine.routine_id = "print-sample"
|
||||
routine.title = "Kür Testdruck"
|
||||
routine.skater_name = "Erika Mustermann"
|
||||
routine.adult_category = "gold"
|
||||
routine.season = "2026/27"
|
||||
routine.rink = RinkDimensions.new()
|
||||
|
||||
_add_section(routine, "Start", 0, [
|
||||
{"from": Vector2(-18.0, -6.0), "to": Vector2(-6.0, 2.0), "kind": "jump", "code": "1A", "label": "Auftakt"},
|
||||
{"from": Vector2(-6.0, 2.0), "to": Vector2(6.0, 6.0), "kind": "spin", "code": "CCoSp", "label": "Pirouette"},
|
||||
{"from": Vector2(6.0, 6.0), "to": Vector2(14.0, 0.0), "kind": "plain", "code": "", "label": ""},
|
||||
], 26.0)
|
||||
_add_section(routine, "Abschnitt 2", 1, [
|
||||
{"from": Vector2(14.0, 0.0), "to": Vector2(0.0, -8.0), "kind": "jump", "code": "3Lz", "label": "Kombination"},
|
||||
{"from": Vector2(0.0, -8.0), "to": Vector2(-12.0, -4.0), "kind": "plain", "code": "", "label": "Übergang"},
|
||||
], 24.0)
|
||||
_add_section(routine, "Step Seq Absch.", 2, [
|
||||
{"from": Vector2(-12.0, -4.0), "to": Vector2(-2.0, 4.0), "kind": "sequence", "code": "StSq", "label": ""},
|
||||
{"from": Vector2(-2.0, 4.0), "to": Vector2(10.0, 2.0), "kind": "plain", "code": "", "label": ""},
|
||||
], 22.0)
|
||||
_add_section(routine, "Abschnitt 4", 3, [
|
||||
{"from": Vector2(10.0, 2.0), "to": Vector2(2.0, 8.0), "kind": "jump", "code": "2T", "label": "Finale"},
|
||||
{"from": Vector2(2.0, 8.0), "to": Vector2(-14.0, 2.0), "kind": "plain", "code": "", "label": ""},
|
||||
], 22.7)
|
||||
|
||||
routine.timeline_labels = [
|
||||
{"time_seconds": 5.0, "text": "Musikstart"},
|
||||
{"time_seconds": 60.0, "text": "Höhepunkt"},
|
||||
]
|
||||
|
||||
var pdf := RoutinePdfExporter.build(routine)
|
||||
if pdf.is_empty():
|
||||
printerr("PDF leer")
|
||||
quit(1)
|
||||
return
|
||||
var path := "user://print-sample.pdf"
|
||||
var file := FileAccess.open(path, FileAccess.WRITE)
|
||||
file.store_buffer(pdf)
|
||||
file.close()
|
||||
print("PDF: ", ProjectSettings.globalize_path(path))
|
||||
quit(0)
|
||||
|
||||
|
||||
func _add_section(
|
||||
routine: Routine,
|
||||
title: String,
|
||||
order: int,
|
||||
entries: Array,
|
||||
seconds: float
|
||||
) -> void:
|
||||
var section := RoutineSection.new()
|
||||
section.section_id = "section-%03d" % (order + 1)
|
||||
section.title = title
|
||||
section.sequence_order = order
|
||||
var share := seconds / maxf(float(entries.size()), 1.0)
|
||||
for entry: Dictionary in entries:
|
||||
var segment := PathSegment.new()
|
||||
segment.segment_id = "seg-%s-%d" % [section.section_id, section.segments.size()]
|
||||
var curve := Curve2D.new()
|
||||
curve.add_point(entry["from"])
|
||||
curve.add_point((entry["from"] + entry["to"]) * 0.5 + Vector2(0.0, -3.0))
|
||||
curve.add_point(entry["to"])
|
||||
segment.curve = curve
|
||||
segment.direction = PathSegment.Direction.FORWARD
|
||||
segment.edge = PathSegment.Edge.OUTSIDE
|
||||
segment.label = entry["label"]
|
||||
if not str(entry["code"]).is_empty():
|
||||
match str(entry["kind"]):
|
||||
"jump":
|
||||
segment.set_element(PathSegment.ElementType.JUMP, entry["code"], 0)
|
||||
"spin":
|
||||
segment.set_element(PathSegment.ElementType.SPIN, entry["code"], 3)
|
||||
segment.set_element_features(
|
||||
PackedStringArray(["difficult_variation_sit", "difficult_exit"])
|
||||
)
|
||||
"sequence":
|
||||
segment.set_element(PathSegment.ElementType.SEQUENCE, entry["code"], 2)
|
||||
segment.apply_geometry_length(segment.get_length_m())
|
||||
segment.duration_seconds = share
|
||||
segment.timing_mode = PathSegment.TimingMode.DURATION
|
||||
section.segments.append(segment)
|
||||
routine.sections.append(section)
|
||||
Loading…
Add table
Add a link
Reference in a new issue